Reorganize imports

Signed-off-by: Nikolaos Karaolidis <nick@karaolidis.com>

hosts/common/configs/user/console/gpg-agent/default.nix

@@ -0,0 +1,69 @@
+{
+  user ? throw "user argument is required",
+  home ? throw "home argument is required",
+}:
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+{
+  home-manager.users.${user} = {
+    # gpg --full-generate-key
+    # gpg --list-secret-keys --keyid-format LONG
+    # gpg --export-secret-keys -a $signature > priv.key
+    # gpg --export -a $signature > pub.key
+    programs.gpg = {
+      enable = true;
+      homedir = "${home}/.local/share/gnupg";
+    };
+
+    services.gpg-agent = {
+      enable = true;
+      defaultCacheTtl = 31536000;
+      maxCacheTtl = 31536000;
+    };
+
+    systemd.user = {
+      services.gpg-agent-import =
+        let
+          init = lib.meta.getExe (
+            pkgs.writeShellApplication {
+              name = "import-gpg-keys";
+              runtimeInputs = with pkgs; [
+                coreutils
+                gnugrep
+                gnupg
+              ];
+              runtimeEnv = {
+                GNUPGHOME = "${home}/.local/share/gnupg";
+                HOME = home;
+              };
+              text = builtins.readFile ./import-gpg-keys.sh;
+            }
+          );
+        in
+        {
+          Unit = {
+            Description = "Auto-import GPG keys";
+            Requires = [
+              "sops-nix.service"
+              "gpg-agent.socket"
+            ];
+            After = [
+              "sops-nix.service"
+              "gpg-agent.socket"
+            ];
+          };
+
+          Service = {
+            Type = "oneshot";
+            ExecStart = init;
+          };
+
+          Install.WantedBy = [ "default.target" ];
+        };
+    };
+  };
+}

hosts/common/configs/user/console/gpg-agent/import-gpg-keys.sh

@@ -0,0 +1,23 @@
+install -d -m 700 "${GNUPGHOME}"
+
+for dir in "${HOME}"/.config/sops-nix/secrets/gpg/*; do
+  keyfile="${dir}/key"
+  passfile="${dir}/pass"
+
+  if [[ ! -f "${keyfile}" ]]; then
+    continue
+  fi
+
+  if [[ -f "${passfile}" ]]; then
+    gpg2 --batch --yes --pinentry-mode loopback --passphrase-file "${passfile}" --import "${keyfile}"
+  else
+    gpg2 --batch --yes --import "${keyfile}"
+  fi
+
+  gpg2 --with-colons --import-options show-only --import "${keyfile}" | grep '^fpr' | cut -d: -f10 | while read -r KEY_ID; do
+    echo "${KEY_ID}:6:" >> "${GNUPGHOME}"/otrust.txt
+  done
+done
+
+gpg2 --import-ownertrust "${GNUPGHOME}"/otrust.txt
+rm "${GNUPGHOME}"/otrust.txt