Reorganize imports

Signed-off-by: Nikolaos Karaolidis <nick@karaolidis.com>
2024-12-21 23:32:29 +02:00
parent 0ae56e6e25
commit 98ce774210
189 changed files with 253 additions and 260 deletions
--- a/hosts/common/configs/user/gui/darktable/default.nix
+++ b/hosts/common/configs/user/gui/darktable/default.nix
@@ -0,0 +1,56 @@
+{
+  user ? throw "user argument is required",
+  home ? throw "home argument is required",
+}:
+{ pkgs, ... }:
+{
+  nixpkgs.overlays = [
+    (final: prev: {
+      darktable = prev.darktable.overrideAttrs (oldAttrs: {
+        patches = oldAttrs.patches or [ ] ++ [ ./better-copy-and-import.patch ];
+      });
+    })
+  ];
+
+  environment.persistence = {
+    "/persist"."${home}/.config/darktable" = { };
+    "/cache"."${home}/.cache/darktable" = { };
+  };
+
+  home-manager.users.${user} =
+    let
+      hald-clut = pkgs.fetchFromGitHub {
+        owner = "cedeber";
+        repo = "hald-clut";
+        rev = "3b3180f82d4dcea1e6e8c5648473539a910d7f49";
+        sha256 = "sha256-R8vyYmcsfk49QsSV3v0QblXcO6U0oIfDyxbHPLwSMdo=";
+      };
+    in
+    {
+      home.packages = with pkgs; [ darktable ];
+
+      xdg.configFile = {
+        "darktable/darktablerc".source = (pkgs.formats.keyValue { }).generate "darktablerc" {
+          "compress_xmp_tags" = "never";
+          "database/create_snapshot" = "once a day";
+          "rating_one_double_tap" = true;
+          "run_crawler_on_start" = true;
+          "ui_last/theme" = "darktable-elegant-darker";
+          "ui_last/grouping" = true;
+          "plugins/darkroom/lut3d/def_path" = "${home}/.config/darktable/luts";
+          "opencl" = false;
+          "plugins/lighttable/overlays/1/0" = 0;
+          "plugins/lighttable/overlays/1/1" = 3;
+          "plugins/lighttable/overlays/1/2" = 3;
+          "plugins/darkroom/modulegroups/last_preset" = "modules: all";
+          "session/base_directory_pattern" = "${home}/Pictures/Darktable";
+          "session/filename_pattern" =
+            "$(EXIF.YEAR)-$(EXIF.MONTH)-$(EXIF.DAY)_$(EXIF.HOUR)-$(EXIF.MINUTE)-$(EXIF.SECOND)_$(CONFLICT_PADDING).$(FILE_EXTENSION)";
+          "session/sub_directory_pattern" = "";
+          "setup_import_directory" = true;
+        };
+
+        "darktable/luts".source = "${hald-clut}/HaldCLUT";
+      };
+    };
+}