Reorganize imports

Signed-off-by: Nikolaos Karaolidis <nick@karaolidis.com>

hosts/common/configs/user/gui/openlens/package.nix

@@ -0,0 +1,34 @@
+# https://github.com/NixOS/nixpkgs/commit/4b29fd82fc757855333ef222742a48d7176eabb9#diff-b8be2fa008db0ba3e0c782ccc6d04465140ce1e59d9e58ba1942c9e9384ce58bL39
+{ lib, pkgs }:
+pkgs.appimageTools.wrapType2 rec {
+  pname = "openlens";
+  version = "6.5.2-366";
+
+  src = pkgs.fetchurl {
+    url = "https://github.com/MuhammedKalkan/OpenLens/releases/download/v${version}/OpenLens-${version}.x86_64.AppImage";
+    sha256 = "sha256-ZAltAS/U/xh4kCT7vQ+NHAzWV7z0uE5GMQICHKSdj8k=";
+  };
+
+  appimageContents = pkgs.appimageTools.extractType2 {
+    inherit pname version src;
+  };
+
+  unshareIpc = false;
+
+  extraInstallCommands = ''
+    install -m 444 -D ${appimageContents}/open-lens.desktop $out/share/applications/${pname}.desktop
+    install -m 444 -D ${appimageContents}/usr/share/icons/hicolor/512x512/apps/open-lens.png \
+       $out/share/icons/hicolor/512x512/apps/${pname}.png
+    substituteInPlace $out/share/applications/${pname}.desktop \
+      --replace 'Icon=open-lens' 'Icon=${pname}' \
+      --replace 'Exec=AppRun' 'Exec=${pname}'
+  '';
+
+  meta = with lib; {
+    description = "Kubernetes IDE";
+    homepage = "https://github.com/MuhammedKalkan/OpenLens";
+    license = licenses.mit;
+    mainProgram = "openlens";
+    platforms = [ "x86_64-linux" ];
+  };
+}