Refactor structure

Signed-off-by: Nikolaos Karaolidis <nick@karaolidis.com>

hosts/eirene/hardware/default.nix

@@ -0,0 +1,95 @@
+{ pkgs, lib, ... }:
+{
+  imports = [
+    ./display.nix
+  ];
+
+  # https://github.com/NixOS/nixos-hardware/tree/master/lenovo/legion/16achg6
+  hardware = {
+    enableAllFirmware = true;
+
+    cpu = {
+      cores = 8;
+      threads = 16;
+      amd.updateMicrocode = true;
+    };
+
+    nvidia = {
+      modesetting.enable = true;
+      powerManagement.enable = true;
+      open = false;
+
+      prime = {
+        offload = {
+          enable = true;
+          enableOffloadCmd = true;
+        };
+        nvidiaBusId = "PCI:1:0:0";
+        amdgpuBusId = "PCI:6:0:0";
+      };
+    };
+
+    graphics = {
+      enable32Bit = true;
+      extraPackages = with pkgs; [
+        amdvlk
+        driversi686Linux.amdvlk
+        rocmPackages.clr
+        rocmPackages.clr.icd
+      ];
+    };
+  };
+
+  boot = {
+    kernelParams = [ "amd_pstate=active" ];
+    kernelModules = [ "kvm-amd" ];
+    initrd.kernelModules = [
+      "nvme"
+      "ahci"
+      "usbhid"
+      "amdgpu"
+    ];
+  };
+
+  nixpkgs = {
+    hostPlatform = "x86_64-linux";
+
+    config = {
+      cudaSupport = true;
+      rocmSupport = true;
+    };
+  };
+
+  powerManagement.enable = true;
+
+  systemd.services.powertop.postStart = builtins.readFile ./scripts/mouse.sh;
+
+  services = {
+    xserver.videoDrivers = [ "nvidia" ];
+    fstrim.enable = true;
+    tlp.settings.DISK_DEVICES = "nvme0n1 nvme1n1";
+  };
+
+  programs.gamescope.env = {
+    __NV_PRIME_RENDER_OFFLOAD = "1";
+    __VK_LAYER_NV_optimus = "NVIDIA_only";
+    __GLX_VENDOR_LIBRARY_NAME = "nvidia";
+  };
+
+  home-manager.sharedModules = [
+    {
+      wayland.windowManager.hyprland.settings = {
+        env = [ "WLR_DRM_DEVICES,$HOME/.config/hypr/card" ];
+        device = [
+          {
+            name = "syna2ba6:00-06cb:ce44-touchpad";
+            sensitivity = 0.5;
+          }
+        ];
+        gestures.workspace_swipe_distance = 600;
+      };
+
+      programs.zsh.loginExtra = lib.mkBefore (builtins.readFile ./scripts/card.sh);
+    }
+  ];
+}

hosts/eirene/hardware/display.nix

@@ -0,0 +1,41 @@
+{ pkgs, ... }:
+{
+  boot.kernelParams = [ "video=eDP-1:2560x1600@165" ];
+
+  programs = {
+    steam.package = pkgs.steam.override {
+      extraEnv.STEAM_FORCE_DESKTOPUI_SCALING = 1.25;
+    };
+
+    gamescope = {
+      args = [
+        "-W 2560"
+        "-H 1600"
+      ];
+    };
+  };
+
+  home-manager.sharedModules = [
+    {
+      wayland.windowManager.hyprland.settings.monitor = "eDP-1, 2560x1600@165, 0x0, 1.25";
+
+      programs = {
+        vscode.userSettings."window.zoomLevel" = (1.25 - 1) / 0.2;
+
+        obs-studio.resolution = {
+          base = {
+            x = 4096;
+            y = 2560;
+          };
+
+          output = {
+            x = 2048;
+            y = 1280;
+          };
+        };
+      };
+
+      theme.cursor.size = 24;
+    }
+  ];
+}

hosts/eirene/hardware/scripts/card.sh

@@ -0,0 +1,10 @@
+AMD=/dev/dri/by-path/pci-0000:06:00.0-card
+NVIDIA=/dev/dri/by-path/pci-0000:01:00.0-card
+
+if [[ -e "${AMD}" ]]; then
+  CARD=${AMD}
+else
+  CARD=${NVIDIA}
+fi
+
+ln -sf "${CARD}" "${HOME}"/.config/hypr/card

hosts/eirene/hardware/scripts/mouse.sh

@@ -0,0 +1,14 @@
+SEARCH_STRINGS=(
+  "Mouse"
+  "Razer DeathAdder Elite"
+  "Razer DeathAdder V3 HyperSpeed"
+)
+
+for search_string in "${SEARCH_STRINGS[@]}"; do
+  echo "Searching for devices matching: ${search_string}"
+
+  for f in $(grep -l "${search_string}" /sys/bus/usb/devices/*/product 2>/dev/null | sed "s/product/power\\/control/"); do
+    echo "Setting power control to 'on' for: ${f}"
+    echo on >| "${f}"
+  done
+done