Add plymouth

Signed-off-by: Nikolaos Karaolidis <nick@karaolidis.com>

hosts/common/configs/getty/default.nix

@@ -0,0 +1,10 @@
+{ config, lib, ... }:
+
+{
+  services.getty.extraArgs = lib.mkIf (config.services.getty.autologinUser != null) [
+    "--skip-login"
+    "--noissue"
+    "--nohints"
+    "--nohostname"
+  ];
+}

hosts/common/configs/persist/default.nix

@@ -1,10 +1,35 @@
-{ inputs, lib, ... }:
+{ inputs, pkgs, ... }:
 
 {
   imports = [ inputs.impermanence.nixosModules.impermanence ];
 
+  boot.initrd.systemd =
+    let
+      bins = with pkgs; [
+        coreutils
+        util-linux
+        findutils
+        btrfs-progs
+      ];
+    in
+    {
+      initrdBin = bins;
+
+      services.impermanence = {
+        description = "Rollback BTRFS subvolumes to a pristine state";
+
+        serviceConfig.Type = "oneshot";
+        wantedBy = [ "initrd.target" ];
+        before = [ "sysroot.mount" ];
+        after = [ "cryptsetup.target" ];
+        unitConfig.DefaultDependencies = "no";
+
+        path = bins;
+        script = builtins.readFile ./impermanence.sh;
+      };
+    };
+
   fileSystems."/persist".neededForBoot = true;
-  boot.initrd.postDeviceCommands = lib.mkAfter (builtins.readFile ./impermanence.sh);
 
   environment.persistence."/persist" = {
     hideMounts = true;

hosts/common/configs/plymouth/default.nix

@@ -0,0 +1,30 @@
+{ pkgs, ... }:
+
+{
+  boot = {
+    plymouth =
+      let
+        theme = "connect";
+      in
+      {
+        enable = true;
+        inherit theme;
+        themePackages = with pkgs; [
+          (adi1090x-plymouth-themes.override { selected_themes = [ theme ]; })
+        ];
+      };
+
+    initrd.verbose = false;
+    consoleLogLevel = 0;
+
+    kernelParams = [
+      "quiet"
+      "loglevel=3"
+      "splash"
+      "boot.shell_on_fail"
+      "rd.systemd.show_status=false"
+      "rd.udev.log_level=3"
+      "udev.log_priority=3"
+    ];
+  };
+}