{ pkgs, ... }:
# AUTO-UPDATE: nix-update --flake obsidian-plugin-excalidraw --subpackage mathjaxToSVG
pkgs.buildNpmPackage (finalAttrs: {
  pname = "obsidian.plugins.excalidraw";
  version = "2.15.1";

  pkg = pkgs.fetchFromGitHub {
    owner = "zsviczian";
    repo = "obsidian-excalidraw-plugin";
    rev = finalAttrs.version;
    hash = "sha256-EsyR5PTZkR+/+5F9mteZ06smbX0mhxtbagO6ZDloHgs=";
  };

  mathjaxToSVG = pkgs.buildNpmPackage {
    pname = "obsidian.plugins.excalidraw.mathjaxToSVG";
    version = "1.0.0";

    src = "${finalAttrs.pkg}/MathjaxToSVG";
    npmDepsHash = "sha256-AosKWlX08dpXNQ2YlrfR6jEInmU02Ztf26nmV19Jxok=";

    configurePhase = ''
      mkdir dist
    '';

    installPhase = ''
      mkdir -p $out
      cp ./dist/index.js $out/index.js
    '';
  };

  src = finalAttrs.pkg;

  patches = [ ./package-lock.patch ];

  npmDepsHash = "sha256-QuhHPLjPpZNKZH7qhOr77CCZS9+ls35+ka4WYOEt4zI=";
  npmPackFlags = [ "--ignore-scripts" ];

  configurePhase = ''
    mkdir dist
    mkdir -p ./MathjaxToSVG/dist
    cp ${finalAttrs.mathjaxToSVG}/index.js ./MathjaxToSVG/dist/index.js
  '';

  installPhase = ''
    mkdir -p $out
    cp ./dist/manifest.json $out/manifest.json
    cp ./dist/main.js $out/main.js
    cp ./dist/styles.css $out/styles.css
  '';
})