{ pkgs, ... }:
let
  entrypoint = pkgs.writeTextFile {
    name = "entrypoint";
    executable = true;
    destination = "/bin/entrypoint";
    text = builtins.readFile ./entrypoint.sh;
  };

  flood-for-transmission = pkgs.runCommandLocal "flood-for-transmission" { } ''
    mkdir -p $out/var/www
    cp -r ${pkgs.flood-for-transmission} $out/var/www/transmission
  '';
in
pkgs.dockerTools.buildImage {
  name = "transmission-protonvpn";
  fromImage = import ../base { inherit pkgs; };

  copyToRoot = pkgs.buildEnv {
    name = "root";
    paths = with pkgs; [
      entrypoint
      flood-for-transmission
      transmission_4
      wireguard-tools
      libnatpmp
      curl
      jq
    ];
    pathsToLink = [
      "/bin"
      "/lib"
      "/share"
      "/var"
    ];
  };

  config = {
    Entrypoint = [ "entrypoint" ];
    ExposedPorts = {
      "9091/tcp" = { };
    };
    WorkingDir = "/var/lib/transmission";
    Volumes = {
      "/etc/transmission" = { };
      "/var/lib/transmission" = { };
    };
    Env = [
      "TRANSMISSION_HOME=/etc/transmission"
      "TRANSMISSION_WEB_HOME=/var/www/transmission"
    ];
  };
}