{ pkgs, ... }:
let
  entrypoint = pkgs.writeTextFile {
    name = "entrypoint";
    executable = true;
    destination = "/bin/entrypoint";
    text = builtins.readFile ./entrypoint.sh;
  };

  # FIXME: https://github.com/fallenbagel/jellyseerr/pull/1505
  jellyseerr = pkgs.jellyseerr.overrideAttrs (
    oldAttrs:
    let
      src = pkgs.fetchFromGitHub {
        owner = "Fallenbagel";
        repo = "jellyseerr";
        tag = "preview-OIDC";
        hash = "sha256-iBnO0WjNqvXfuJMoS6z/NmYgtW5FQ9Ptp9uV5rODIf8=";
      };
    in
    {
      inherit src;
      pnpmDeps = (pkgs.pnpm_9.override { nodejs = pkgs.nodejs_22; }).fetchDeps {
        inherit src;
        inherit (oldAttrs) pname version;
        fetcherVersion = 2;
        hash = "sha256-Ek2z1KIel3egwZ9dGU7rJQEyhukmXw5chsfvI2w8v28=";
      };
    }
  );
in
pkgs.dockerTools.buildImage {
  name = "jellyseerr";
  fromImage = import ../base { inherit pkgs; };

  copyToRoot = pkgs.buildEnv {
    name = "root";
    paths = with pkgs; [
      entrypoint
      jellyseerr
      curl
      jq
    ];
    pathsToLink = [
      "/bin"
      "/lib"
    ];
  };

  config = {
    Entrypoint = [ "entrypoint" ];
    Env = [ "CONFIG_DIRECTORY=/var/lib/jellyseerr" ];
    WorkingDir = "/var/lib/jellyseerr";
    Volumes = {
      "/var/lib/jellyseerr" = { };
    };
    ExposedPorts = {
      "5055/tcp" = { };
    };
  };
}