{ pkgs, ... }:
# AUTO-UPDATE: nix-update --flake obsidian-plugin-languagetool
pkgs.stdenv.mkDerivation (finalAttrs: {
  pname = "languagetool";
  version = "0.3.7";

  src = pkgs.fetchFromGitHub {
    owner = "Clemens-E";
    repo = "obsidian-languagetool-plugin";
    rev = finalAttrs.version;
    hash = "sha256-OsdOOrXNoraKuFPqvgn6pj6ZagEbiFCJyQ529eyZXUU=";
  };

  patches = [
    # Fix variety typo
    (builtins.fetchurl {
      url = "https://patch-diff.githubusercontent.com/raw/Clemens-E/obsidian-languagetool-plugin/pull/132.patch";
      sha256 = "sha256:13lzp0920h1kc9yl3r04r505zb417hlciyiwii0fm5b12g35av8v";
    })
    ./settings-notification.patch
  ];

  offlineCache = pkgs.fetchYarnDeps {
    yarnLock = finalAttrs.src + "/yarn.lock";
    hash = "sha256-749RGQmg9Mte7TR6k3qP6xcb8+rj/C60LYLbF8j8gNc=";
  };

  nativeBuildInputs = with pkgs; [
    nodejs
    yarnConfigHook
    yarnBuildHook
    npmHooks.npmInstallHook
  ];

  installPhase = ''
    mkdir -p $out
    cp ./manifest.json $out/manifest.json
    cp ./main.js $out/main.js
    cp ./styles.css $out/styles.css
  '';
})