{ pkgs, ... }:
# AUTO-UPDATE: nix-update --flake comentario --version=branch=dev --subpackage frontend
pkgs.buildGo125Module (finalAttrs: {
  pname = "comentario";
  version = "3.14.0-unstable-2025-09-20";

  src = pkgs.fetchFromGitLab {
    owner = "comentario";
    repo = "comentario";
    # FIXME: Stable rev once type error is fixed
    rev = "73cf8040cb9adb31794ec780e5905c2e747ca63f";
    hash = "sha256-8rch1sL81wQblaUBebUA/C2HxtAfYHPadt2X2qJWJIk=";
  };

  patches = [ ./superuser-claim.patch ];

  vendorHash = "sha256-AOI/WnVkrSgJlT2FtYOTuifOPw8sfc4C0g/prVkvJlA=";

  nativeBuildInputs = with pkgs; [
    go-swagger
    makeWrapper
  ];

  subPackages = [ "." ];

  frontend = pkgs.stdenv.mkDerivation (finalFrontendAttrs: {
    inherit (finalAttrs)
      pname
      version
      src
      patches
      ;

    missingHashes = ./missing-hashes.json;
    offlineCache = pkgs.yarn-berry.fetchYarnBerryDeps {
      inherit (finalFrontendAttrs) src patches missingHashes;
      hash = "sha256-dYk85+e9C0yHZ9jYgsefStZfyQFZZku+Z4Kn7bN4Qjw=";
    };

    nativeBuildInputs = with pkgs; [
      nodejs
      openapi-generator-cli
      hugo
      yarn-berry
      yarn-berry.yarnBerryConfigHook
    ];

    env = {
      CYPRESS_INSTALL_BINARY = "0";
      YARN_NODE_LINKER = "node-modules";
    };

    buildPhase = ''
      (cd frontend && openapi-generator-cli generate -i ../resources/swagger/swagger.yml -g typescript-angular -o generated-api)
      yarn run build:prod
    '';

    installPhase = ''
      cp -r build/frontend $out
    '';
  });

  preBuild = ''
    go generate
  '';

  installPhase = ''
    mkdir -p $out/bin
    cp -r $GOPATH/bin/comentario $out/bin/${finalAttrs.pname}

    wrapProgram $out/bin/${finalAttrs.pname} \
      --add-flags "--static-path=${finalAttrs.frontend}"
  '';

  meta.mainProgram = finalAttrs.pname;
})