{ user, home }:
{ pkgs, ... }:
{
  environment.persistence = {
    "/persist/state" = {
      "${home}/.config/darktable/data.db" = { };
      "${home}/.config/darktable/library.db" = { };
    };
    "/persist/cache"."${home}/.cache/darktable" = { };
  };

  home-manager.users.${user} = {
    home.packages = with pkgs; [
      darktable
      exiftool
    ];

    xdg.configFile = {
      "darktable/darktablerc".source = (pkgs.formats.keyValue { }).generate "darktablerc" {
        "compress_xmp_tags" = "never";
        "database/create_snapshot" = "once a day";
        "rating_one_double_tap" = true;
        "run_crawler_on_start" = true;
        "ui_last/theme" = "darktable-elegant-darker";
        "ui_last/grouping" = true;
        "plugins/darkroom/lut3d/def_path" = "${home}/.config/darktable/luts";
        "opencl" = true;
        "plugins/lighttable/overlays/1/0" = 0;
        "plugins/lighttable/overlays/1/1" = 3;
        "plugins/lighttable/overlays/1/2" = 3;
        "plugins/darkroom/modulegroups/last_preset" = "modules: all";
        "send_to_trash" = false;
        "session/base_directory_pattern" = "${home}/Pictures/Darktable";
        "session/filename_pattern" =
          "$(EXIF.YEAR)-$(EXIF.MONTH)-$(EXIF.DAY)_$(EXIF.HOUR)-$(EXIF.MINUTE)-$(EXIF.SECOND)_$(CONFLICT_PADDING).$(FILE_EXTENSION)";
        "session/sub_directory_pattern" = "";
        "setup_import_directory" = true;
        "lua/script_manager/check_update" = false;
      };

      "darktable/luarc".text = ''
        require "tools/script_manager"
      '';

      "darktable/lua/lib".source = "${pkgs.darktable-lua-scripts}/lib";
      "darktable/lua/tools/script_manager.lua".source =
        "${pkgs.darktable-lua-scripts}/tools/script_manager.lua";

      "darktable/luts".source = pkgs.darktable-hald-clut;
    };
  };
}