{ pkgs, ... }:
# AUTO-UPDATE: nix-update --flake obsidian-plugin-excalidraw --subpackage mathjaxToSVG
pkgs.buildNpmPackage rec {
  pname = "obsidian.plugins.excalidraw";
  version = "2.12.4";

  pkg = pkgs.fetchFromGitHub {
    owner = "zsviczian";
    repo = "obsidian-excalidraw-plugin";
    rev = version;
    hash = "sha256-mnNNv9U918h8ZDyyi/ZBH/BsaBCpLKHAn5hscmxL/Xg=";
  };

  mathjaxToSVG = pkgs.buildNpmPackage {
    pname = "obsidian.plugins.excalidraw.mathjaxToSVG";
    version = "1.0.0";

    src = "${pkg}/MathjaxToSVG";
    npmDepsHash = "sha256-AosKWlX08dpXNQ2YlrfR6jEInmU02Ztf26nmV19Jxok=";

    configurePhase = ''
      mkdir dist
    '';

    installPhase = ''
      mkdir -p $out
      cp ./dist/index.js $out/index.js
    '';
  };

  src = pkg;

  npmDepsHash = "sha256-x8ToewyXv9JmYxLOhH99huRkKvbtkWvM07vYqA2R5C0=";
  npmPackFlags = [ "--ignore-scripts" ];

  configurePhase = ''
    mkdir dist
    mkdir -p ./MathjaxToSVG/dist
    cp ${mathjaxToSVG}/index.js ./MathjaxToSVG/dist/index.js
  '';

  installPhase = ''
    mkdir -p $out
    cp ./dist/manifest.json $out/manifest.json
    cp ./dist/main.js $out/main.js
    cp ./dist/styles.css $out/styles.css
  '';
}