{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    disko = {
      url = "github:nix-community/disko/latest";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    secrets = {
      url = "git+https://git.karaolidis.com/karaolidis/nix-secrets.git";
      flake = false;
    };

    systems.url = "github:nix-systems/default";

    nur = {
      url = "github:nix-community/NUR";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs.systems.follows = "systems";
    };

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-input-patcher = {
      url = "github:jfly/flake-input-patcher";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        systems.follows = "systems";
      };
    };

    quadlet-nix.url = "github:SEIAROTg/quadlet-nix";

    nvidia-patch = {
      url = "github:icewind1991/nvidia-patch-nixos";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        utils.follows = "flake-utils";
      };
    };

    astal = {
      url = "github:aylur/astal";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    ags = {
      url = "github:aylur/ags";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        astal.follows = "astal";
      };
    };

    spicetify-nix = {
      url = "github:Gerg-L/spicetify-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        systems.follows = "systems";
      };
    };
  };

  outputs =
    inputs:
    let
      mkInputs =
        system:
        let
          patcher = inputs.flake-input-patcher.lib.${system};
        in
        patcher.patch inputs (import ./patches.nix { inherit patcher; });

      mkNixosConfiguration =
        inputs: system: modules:
        inputs.nixpkgs.lib.nixosSystem {
          inherit system modules;
          specialArgs = { inherit inputs system; };
        };
    in
    (
      let
        system = "x86_64-linux";
        inputs = mkInputs system;

        pkgs = import inputs.nixpkgs {
          inherit system;
          config.allowUnfree = true;
        };

        treefmt = inputs.treefmt-nix.lib.evalModule pkgs ./treefmt.nix;
      in
      {
        nixosConfigurations = {
          installer = mkNixosConfiguration inputs system [ ./hosts/installer ];
          himalia = mkNixosConfiguration inputs system [ ./hosts/himalia ];
          elara = mkNixosConfiguration inputs system [ ./hosts/elara ];
          jupiter = mkNixosConfiguration inputs system [ ./hosts/jupiter ];
          jupiter-vps = mkNixosConfiguration inputs system [ ./hosts/jupiter-vps ];
        };

        devShells.${system} = import ./hosts/common/shells { inherit pkgs; };
        lib.${system} = import ./lib { inherit pkgs; };
        packages.${system} = import ./packages { inherit pkgs inputs system; };

        formatter.${system} = treefmt.config.build.wrapper;
        checks.formatting.${system} = treefmt.config.build.check inputs.self;
      }
    );
}