{
  user ? throw "user argument is required",
  home ? throw "home argument is required",
}:
{
  config,
  lib,
  pkgs,
  ...
}:
let
  hmConfig = config.home-manager.users.${user};
in
{
  home-manager.users.${user} = {
    gtk = {
      enable = true;

      theme = {
        package = pkgs.adw-gtk3;
        name = "adw-gtk3-dark";
      };

      font = {
        name = builtins.head hmConfig.theme.font.sansSerif.names;
        package = builtins.head hmConfig.theme.font.sansSerif.packages;
        inherit (hmConfig.theme.font) size;
      };

      iconTheme = {
        name = builtins.head hmConfig.theme.icon.names;
        package = builtins.head hmConfig.theme.icon.packages;
      };

      gtk2.configLocation = "${home}/.config/gtk-2.0/gtkrc";
      gtk3.extraCss = "@import './theme.css';";
      gtk4.extraCss = "@import './theme.css';";
    };

    home = {
      pointerCursor.gtk.enable = true;

      file =
        {
          ".icons/default/index.theme".enable = false;
        }
        // builtins.listToAttrs (
          builtins.map (name: {
            name = ".icons/${name}";
            value.enable = false;
          }) (hmConfig.theme.icon.names ++ hmConfig.theme.cursor.names)
        );
    };

    theme.template = {
      "${home}/.config/gtk-3.0/theme.css".source = ./theme.css;
      "${home}/.config/gtk-4.0/theme.css".source = ./theme.css;
    };

    theme.initExtraConfig = "${
      lib.meta.getExe (
        pkgs.writeShellApplication {
          name = "theme-gtk";
          runtimeInputs = with pkgs; [
            dbus
            dconf
          ];
          text = ''
            mode=$(cat "${hmConfig.theme.configDir}/mode")

            if [ "$mode" = "light" ]; then
              gtk_theme="adw-gtk3"
            else
              gtk_theme="adw-gtk3-dark"
            fi

            if [[ -v DBUS_SESSION_BUS_ADDRESS ]]; then
              dconf_dbus_run_session=""
            else
              dconf_dbus_run_session="dbus-run-session --dbus-daemon=dbus-daemon"
            fi

            $dconf_dbus_run_session bash -c "
              dconf write /org/gnome/desktop/interface/gtk-theme \"'$gtk_theme'\"
              dconf write /org/gnome/desktop/interface/color-scheme \"'prefer-$mode'\"
            "
          '';
        }
      )
    } &";
  };
}