{ pkgs, ... }:
# AUTO-UPDATE: nix-update --flake obsidian-plugin-excalidraw --subpackage mathjaxToSVG
pkgs.buildNpmPackage (finalAttrs: {
  pname = "obsidian.plugins.excalidraw";
  version = "2.14.0";

  pkg = pkgs.fetchFromGitHub {
    owner = "zsviczian";
    repo = "obsidian-excalidraw-plugin";
    rev = finalAttrs.version;
    hash = "sha256-QUPL9WYpfhFf5yFZA7Hh1fGdFxiCwdVMZ6OeF7lypso=";
  };

  mathjaxToSVG = pkgs.buildNpmPackage {
    pname = "obsidian.plugins.excalidraw.mathjaxToSVG";
    version = "1.0.0";

    src = "${finalAttrs.pkg}/MathjaxToSVG";
    npmDepsHash = "sha256-AosKWlX08dpXNQ2YlrfR6jEInmU02Ztf26nmV19Jxok=";

    configurePhase = ''
      mkdir dist
    '';

    installPhase = ''
      mkdir -p $out
      cp ./dist/index.js $out/index.js
    '';
  };

  src = finalAttrs.pkg;

  npmDepsHash = "sha256-zfLHskffLfsJoQ2Ftu30wjZ+d3t3C8HqSTUyEHP0NAQ=";
  npmPackFlags = [ "--ignore-scripts" ];

  configurePhase = ''
    mkdir dist
    mkdir -p ./MathjaxToSVG/dist
    cp ${finalAttrs.mathjaxToSVG}/index.js ./MathjaxToSVG/dist/index.js
  '';

  installPhase = ''
    mkdir -p $out
    cp ./dist/manifest.json $out/manifest.json
    cp ./dist/main.js $out/main.js
    cp ./dist/styles.css $out/styles.css
  '';
})