nix/flake.nix

{
  inputs = {
    # Configuration
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Packages
    nur = {
      url = "github:nix-community/NUR";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-parts.follows = "flake-parts";
      };
    };

    # DevOps
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-input-patcher = {
      url = "github:jfly/flake-input-patcher";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        systems.follows = "systems";
      };
    };

    # Personal
    lib = {
      # FIXME: https://github.com/NixOS/nix/issues/12281
      url = "git+https://git.karaolidis.com/karaolidis/nix-lib.git";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        treefmt-nix.follows = "treefmt-nix";
      };
    };

    sas = {
      # FIXME: https://github.com/NixOS/nix/issues/12281
      url = "git+ssh://git@karaolidis.com/karaolidis/nix-sas.git";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        lib.follows = "lib";
        treefmt-nix.follows = "treefmt-nix";
      };
    };

    secrets = {
      # FIXME: https://github.com/NixOS/nix/issues/12281
      url = "git+ssh://git@karaolidis.com/karaolidis/nix-secrets.git";
      flake = false;
    };

    # Hardware
    disko = {
      url = "github:nix-community/disko/latest";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    lanzaboote = {
      url = "github:nix-community/lanzaboote";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-compat.follows = "flake-compat";
        flake-parts.follows = "flake-parts";
      };
    };

    nixos-wsl = {
      url = "github:karaolidis/NixOS-WSL/extra-files";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-compat.follows = "flake-compat";
      };
    };

    # Applications
    nvf = {
      url = "github:NotAShelf/nvf";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-compat.follows = "flake-compat";
        flake-parts.follows = "flake-parts";
        systems.follows = "systems";
      };
    };

    quadlet-nix.url = "github:SEIAROTg/quadlet-nix";

    nvidia-patch = {
      url = "github:icewind1991/nvidia-patch-nixos";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        utils.follows = "flake-utils";
      };
    };

    astal = {
      url = "github:aylur/astal";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    ags = {
      url = "github:aylur/ags";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        astal.follows = "astal";
      };
    };

    spicetify-nix = {
      url = "github:Gerg-L/spicetify-nix";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        systems.follows = "systems";
      };
    };

    # Transitive Dependencies
    systems.url = "github:nix-systems/default";

    flake-parts.url = "github:hercules-ci/flake-parts";

    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs.systems.follows = "systems";
    };

    flake-compat.url = "https://flakehub.com/f/edolstra/flake-compat/1.tar.gz";
  };

  outputs =
    unpatchedInputs:
    let
      patchInputs =
        system:
        let
          patcher = unpatchedInputs.flake-input-patcher.lib.${system};
          patches = import ./patches.nix { inherit patcher; };
        in
        if patches != { } then patcher.patch unpatchedInputs patches else unpatchedInputs;

      mkNixosConfiguration =
        inputs: system: modules:
        inputs.nixpkgs.lib.nixosSystem {
          inherit system modules;
          specialArgs = { inherit inputs system; };
        };
    in
    {
      overlays.default = import ./overlays;
    }
    // (
      let
        system = "x86_64-linux";
        inputs = patchInputs system;

        pkgs = import inputs.nixpkgs {
          inherit system;
          config.allowUnfree = true;
          overlays = [
            inputs.lib.overlays.default
            inputs.self.overlays.default
          ];
        };

        treefmt = inputs.treefmt-nix.lib.evalModule pkgs ./treefmt.nix;
      in
      {
        nixosConfigurations = {
          installer = mkNixosConfiguration inputs system [ ./hosts/installer ];
          himalia = mkNixosConfiguration inputs system [ ./hosts/himalia ];
          elara = mkNixosConfiguration inputs system [ ./hosts/elara ];
          jupiter = mkNixosConfiguration inputs system [ ./hosts/jupiter ];
          jupiter-vps = mkNixosConfiguration inputs system [ ./hosts/jupiter-vps ];
        };

        devShells.${system} = import ./hosts/common/shells { inherit pkgs; };
        packages.${system} = import ./packages { inherit pkgs; };
        formatter.${system} = treefmt.config.build.wrapper;
        checks.${system}.formatting = treefmt.config.build.check inputs.self;
      }
    );
}